(vl-load-com);;一部関数はこれをしておかないと使えない「vla-」が先頭につくもの
((lambda( / spath );;互換CADチェック
   (setq spath(getvar "ACADPREFIX")  )
   (if(vl-string-search "ARES" spath)(setq command_for_alter "ARES")
     (if(vl-string-search "IJ" spath)(setq command_for_alter "IJCAD")
       ))
   ))

(defun kozai_database( str_stf / ls_data ls_shape real_weight)
  ;;名前の次が単位体積重量、そのあとは3つ一組で
  ;;(X,Y,その点から前の点へ向けてが円弧であれば半径)となる
  ;;上から見て時計回りになるようにしておく
  (setq
   ls_data
   (list
    (list "H-300x300x10x15" 93.0 ;;単重;;L左R右T上U下I内O外FフランジWウェブ
          150   -150 0    -150 -150 0  -150 -135 0    -23  -135 0;;;RUFOO-LUFII
          -5    -117 -18  -5   117  0  -23  135  -18  -150 135  0;;;LUW  -LTFOI
          -150  150  0    150  150  0  150  135  0    23   135  0;;;LTFOO-RTFII
          5     117  -18  5    -117 0  23   -135 -18  150  -135 0);;RTW  -RUFOI
    (list "H-350x350x12x19" 135.0
          175   -175 0    -175 -175 0  -175 -156 0   -26  -156 0
          -6    -136 -20  -6   136  0  -26  156  -20 -175 156  0
          -175  175  0    175  175  0  175  156  0   26   156  0
          6     136  -20  6    -136 0  26   -156 -20 175  -156 0)
    (list "H-400x400x13x21" 172.0
          200   -200 0    -200 -200 0  -200  -179 0   -28.5 -179 0
          -6.5  -157 -22  -6.5 157  0  -28.5 179  -22 -200  179  0
          -200  200  0    200  200  0  200   179  0   28.5  179  0
          6.5   157  -22  6.5  -157 0  28.5  -179 -22 200   -179 0)
    (list "H-500x500x25x25" 289.0
          250   -250 0   -250  -250 0  -250  -225 0   -38.5 -225 0
          -12.5 -199 -26 -12.5 199  0  -38.5 225  -26 -250  225  0
          -250  250  0   250   250  0  250   225  0   38.5  225  0
          12.5  199  -26 12.5  -199 0  38.5  -225 -26 250   -225 0)
    
    (list "CH-125x65x6x8" 13.4
          65 -62.5 0  0 -62.5 0  0 62.5 0  65 62.5 0;;右下→右上
          65 60.72358574009275 0;;右上から鉛直に少し下
          61.34862297099153 56.73880694772572 4;;フランジ上外
          13.30275405801876 52.53533808858924 0;;フランジ上内
          6 44.56578050385542 -8   6 -44.56578050385360  0;;ウェブ上-下
          13.30275405801876 -52.53533808858924 -8;;フランジ下内
          61.34862297099153 -56.73880694772572 0;;フランジ下外
          65 -60.72358574009275 4);;右下から鉛直に少し上
    (list "CH-150x75x6.5x10" 18.6
          75 -75 0  0 -75 0  0 75 0  75 75 0
          75 72.52000149876244 0    70.43577871373781 67.53902800830371    5
          15.62844257252436 62.74400741789396 0   6.5 52.78206043697628    -10
          6.5 -52.78206043697628 0  15.62844257252436 -62.74400741789349   -10
          70.43577871373781     -67.53902800830371 0 75 -72.52000149876244 5)
    (list "CH-150x75x9x12.5" 24.0
          75 -75 0 0 -75 0 0 75 0 75 75 0
          75 72.27414058197064 0 68.15366807060673 64.80268034628261     7.5
          22.69266385878655    60.82535784524316 0 9  45.88243737386756  -15
          9 -45.88243737386756 0 22.69266385878655 -60.82535784524361    -15
          68.15366807060673   -64.80268034628261 0 75 -72.27414058197064 7.5)
    (list "CH-180x75x7x105" 21.4
          75 -90 0 0 -90 0 0 90 0 75 90 0
          75 87.52511486338699 0 69.97935658511210 82.04604402388259     5.5
          17.04128682977716    77.41456305134670 0 7 66.45642137233699   -11
          7 -66.45642137233699 0 17.04128682977716 -77.41456305134670    -11
          69.97935658511210   -82.04604402388259 0 75 -87.52511486338699 5.5)
    (list "CH-200x70x7x10" 21.1
          70 -100 0 0 -100 0 0 100 0 70 100 0
          70 97.79571435816206 0 64.97935658511142 92.31664351865765     5.5
          17.04128682977534    88.12260586375169 0 7 77.16446418474197   -11
          7 -77.16446418474197 0 17.04128682977534 -88.12260586375122    -11
          64.97935658511142   -92.31664351865765 0 70 -97.79571435816206 5.5)
    (list "CH-200x80x7.5x11" 24.6
          80 -100 0 0 -100 0 0 100 0 80 100 0
          80 97.66945109691825 0 74.52293445648592 91.69228290836782     6
          18.45413108702814    86.78689823607783 0 7.5 74.83256185897698 -12
          7.5 -74.83256185897608 0  18.45413108702814 -86.78689823607783 -12
          74.52293445648592   -91.69228290836782 0 80 -97.66945109691825 6)
    (list "CH-200x90x8x13.5" 30.3
          90 -100 0 0 -100 0 0 100 0 90 100 0
          90 96.50135342268459 0 83.61009019923313 89.52799053604257     7
          20.77981960153374    84.03105413247795 0 8   70.08432835919347 -14
          8 -70.08432835919257 0  20.77981960153374   -84.03105413247748 -14
          83.61009019923313   -89.52799053604257 0 90 -96.50135342268459 7)
    (list "CH-250x90x9x13" 34.6
          90 -125 0 0 -125 0 0 125 0 90 125 0
          90 121.9576090909209 0 83.61009019923404 114.9842462042788     7
          21.77981960153193   109.5747984642412  0 9 95.62807269095628   -14
          9 -95.62807269095628 0 21.77981960153193  -109.5747984642412   -14
          83.61009019923404  -114.9842462042788  0 90 -121.9576090909209 7)
    (list "CH-250x90x11x14.5" 40.2
          90 -125 0 0 -125 0 0 125 0 90 125 0
          90 121.7446171884235 0  82.24082381335529 113.2769622546438   8.5
          26.51835237329215   108.4018776999892  0 11 91.46656783242997 -17
          11 -91.46656783242997 0  26.51835237329215 -108.4018776999892 -17
          82.24082381335529 -113.2769622546429 0 90 -121.7446171884225 8.5)
    (list "CH-300x90x9x13" 38.1
          90 -150 0 0 -150 0 0 150 0 90 150 0
          90 146.9576090909217 0  83.61009019923358 139.9842462042798 7
          21.77981960153193 134.5747984642403 0  9 120.6280726909572 -14
          9 -120.6280726909572 0  21.77981960153193 -134.5747984642403 -14
          83.61009019923358 -139.9842462042798 0 90 -146.9576090909217 7)
    (list "CH-300x90x10x15.5" 43.8
          90 -150 0 0 -150 0 0 150 0 90 150 0
          90 146.7046926942025 0 81.32797955610294 137.2408430623309 9.5
          27.34404088779593 132.5178604163757 0 10 113.5901611526324 -19
          10 -113.5901611526324 0 27.34404088779593 -132.5178604163757 -19
          81.32797955610294 -137.2408430623309 0 90 -146.7046926942025 9.5)
    (list "CH-300x90x12x16" 48.6
          90 -150 0 0 -150 0 0 150 0 90 150 0
          90 146.1172040306751 0 81.32797955610204 136.6533543988034 9.5
          29.34404088779411 132.1053490799022 0 12 113.1776498161589 -19
          12 -113.1776498161571 0 29.34404088779411 -132.1053490799027 -19
          81.32797955610204 -136.6533543988034 0 90 -146.1172040306751 9.5)
    (list "CH-380x100x10.5x16" 54.5
          100 -190 0 0 -190 0 0 190 0 100 190 0
          100 186.1620982589406 0  91.78440168472661 177.1963459761150 9
          26.93119663054131 171.5224257405534 0 10.5 153.5909211749022 -18
          10.5 -153.5909211749013 0  26.93119663054131 -171.5224257405539 -18
          91.78440168472661 -177.1963459761150 0 100 -186.1620982589406 9)
    (list "CH-380x100x13x16.5" 62.0
          100 -190 0 0 -190 0 0 190 0 100 190 0
          100 185.5527374295343 0 91.78440168472889 176.5869851467087 9
          29.43119663054313 171.1317865699602 0 13 153.2002820043089 -36
          13 -153.2002820043089 0 29.43119663054313 -171.1317865699602 -36
          91.78440168472889 -176.5869851467087 0 100 -185.5527374295343 9)
    (list "CH-380x100x13x20" 67.3
          100 -190 0 0 -190 0 0 190 0 100 190 0
          100 184.8017309515862 0 89.04586891297185 172.8473945744854 12
          34.90826217405629 168.1109677144059 0 13 144.2022949602042 -24
          13 -144.2022949602042 0 34.90826217405629 -168.1109677144059 -24
          89.04586891297231 -172.8473945744854 0 100 -184.8017309515862 12)

    (list "L-65x65x6" 5.91
          0 0    0   0    65 0     2  65 0  6 61 4;;左下-左内上
          6 14.5 0   14.5 6  -8.5  61 6  0  65 2 4  65 0 0);;左内下-右下
    (list "L-65x65x8" 7.66
          0 0    0   0    65 0     2  65 0  8  59 6
          8 16.5 0   16.5 8  -8.5  59 8  0  65 2  6  65 0 0)
    (list "L-75x75x6" 6.85
          0 0    0   0    75 0     2  75 0  6  71 4
          6 14.5 0   14.5 6  -8.5  71 6  0  75 2  4  75 0 0)
    (list "L-75x75x9" 9.96
          0 0    0   0    75 0     3  75 0  9  69 3
          9 17.5 0   17.5 9  -8.5  69 9  0  75 3  6  75 0 0)
    (list "L-75x75x12" 13.0
          0  0    0   0    75  0     6  75 0  12 69 6
          12 20.5 0   20.5 12  -8.5  69 12 0  75 6  6  75 0 0)
    (list "L-90x90x6" 8.28
          0 0  0   0  90 0    1  90 0  6  85 5
          6 16 0   16 6  -10  85 6  0  90 1  5  90 0 0)
    (list "L-90x90x7" 9.59
          0 0  0  0  90 0    2  90 0  7  85 5
          7 17 0  17 7  -10  85 7  0  90 2  5  90 0 0)
    (list "L-90x90x10" 13.3
          0  0  0   0  90 0    3  90 0  10 83 7
          10 20 0   20 10 -10  83 10 0  90 3  7  90 0 0)
    (list "L-90x90x13" 17.0
          0  0  0   0  90 0    6  90 0  13 83 7
          13 23 0   23 13 -10  83 13 0  90 6  7  90 0 0)
    (list "L-100x100x7" 10.7
          0 0  0   0  100 0    2  100 0  7   95 5
          7 17 0   17 7   -10  95 7   0  100 2  7  100 0 0)
    (list "L-100x100x10" 14.9
          0  0  0   0  100 0    3  100 0  10  93 7
          10 20 0   20 10  -10  93 10  0  100 3  7  100 0 0)
    (list "L-120x120x8" 14.7
          0 0  0   0  120 0    3   120 0  8   115 5
          8 20 0   20 8   -12  115 8   0  120 3   5  120 0 0)
    (list "L-130x130x9" 17.9
          0 0  0   0  130 0    3   130 0  9   124 6
          9 21 0   21 9   -12  124 9   0  130 3   6  130 0 0)
    (list "L-130x130x12" 23.4
          0  0  0   0  130 0    3.5   130 0  12  121.5 8.5
          12 24 0   24 12  -12  121.5 12  0  130 3.5   8.5  130 0 0)
    (list "L-150x150x12" 27.3
          0  0  0   0  150 0    5   150 0  12  143 7
          12 26 0   26 12  -14  143 12  0  150 5   7  150 0 0)
    (list "L-150x150x15" 33.6
          0  0  0   0  150 0    5   150 0  15  140 10
          15 29 0   29 15  -14  140 15  0  150 5   10  150 0 0)

    (list "H(m)-594x302x14x23" 170.0
          151  -297 0    -151 -297 0  -151 -274 0    -35  -274 0
          -7   -246 -28  -7   246  0  -35  274  -28  -151 274  0
          -151 297  0    151  297  0  151  274  0    35   274  0
          7    246  -28  7    -246 0  35   -274 -28  151  -274 0)
    (list "H(m)-588x300x12x20" 125.0
          150  -294 0    -150 -294 0  -150 -274 0    -34  -274 0
          -6   -246 -28  -6   246  0  -34  274  -28  -150 274  0
          -150 294  0    150  294  0  150  274  0    34   274  0
          6    246  -28  6    -246 0  34   -274 -28  150  -274 0)
    (list "H(m)-700x300x13x24" 182.0
          150  -350 0    -150 -350 0  -150  -326 0    -34.5 -326 0
          -6.5 -298 -28  -6.5 298  0  -34.5 326  -28  -150  326  0
          -150 350  0    150  350  0  150   326  0    34.5  326  0
          6.5  298  -28  6.5  -298 0  34.5  -326 -28  150   -326 0)
    (list "H(m)-800x300x14x26" 207.0
          150  -400 0    -150 -400 0  -150 -374 0    -35  -374 0
          -7   -346 -28  -7   346  0  -35  374  -28  -150 374  0
          -150 400  0    150  400  0  150  374  0    35   374  0
          7    346  -28  7    -346 0  35   -374 -28  150  -374 0)
    (list "H(m)-900x300x16x28" 240.0
          150  -450 0    -150 -450 0  -150 -422 0    -36  -422 0
          -8   -394 -28  -8   394  0  -36  422  -28  -150 422  0
          -150 450  0    150  450  0  150  422  0    36   422  0
          8    394  -28  8    -394 0  36   -422 -28  150  -422 0)
    (list "H(m)-912x302x18x34" 283.0
          151  -456 0    -151 -456 0  -151 -422 0    -27  -422 0
          -9   -404 -18  -9   404  0  -27  422  -18  -151 422  0
          -151 456  0    151  456  0  151  422  0    27   422  0
          9    404  -18  9    -404 0  27   -422 -18  151  -422 0)
    )
   )

  (if str_stf
      (if(setq ls_data(assoc str_stf ls_data))
          (progn
            (setq real_weight(cadr ls_data))
            (list(cddr ls_data)real_weight)
            )
        (progn
          (alert(strcat "[" str_stf "]はデータベースにありません"))
          (quit)
          )
        )
    (mapcar 'car ls_data)
    )
  )

(defun c:data_poly( / );;鋼材ポリラインデータ取得
  ;;スタート地点がわかるように閉じていないポリラインを使うのが良い
  (setq eset(ssget)tmpl(ssname eset 0)ed(entget tmpl)ppL(list)rrL(list)rr0 nil)
  (while(setq pp(assoc 10 ed))
    (setq rr(cdr(nth(+ 3(vl-position pp ed))ed))ed(vl-remove pp ed) pp(cdr pp))
    (if(null rr0)(setq pps pp)
      (if(= rr0 0)(setq rrL(cons 0 rrL))
        (setq rrL(cons(/(*(distance pp0 pp)(1+(expt rr0 2))0.25)rr0)rrL))))
    (setq ppL(cons pp ppL)pp0 pp rr0 rr)
    )
  (if(= rr0 0)(setq rrL(cons 0 rrL))
    (setq rrL(cons(/(*(distance pp0 pps)(1+(expt rr0 2))0.5)rr0)rrL)))
  (setq xL(mapcar '(lambda(a / b)(setq b(car a))
                     (if(=(abs(-(atof(rtos b 2 6))(atoi(rtos b 2 6))))0)
                         (rtos b 2 0)(rtos b 2 16)))ppL);;
        yL(mapcar '(lambda(a / b)(setq b(cadr a))
                     (if(=(abs(-(atof(rtos b 2 6))(atoi(rtos b 2 6))))0)
                         (rtos b 2 0)(rtos b 2 16)))ppL);;
        rL(mapcar '(lambda(b)
                     (if(=(abs(-(atof(rtos b 2 6))(atoi(rtos b 2 6))))0)
                         (rtos(abs b)2 0)(rtos(abs b)2 16)))rrL);;
        axL(mapcar 'atof xL)ayL(mapcar 'atof yL)
        ss(apply '+(mapcar '(lambda(x2 x1 y2 y1)(*(- x2 x1)(+ y2 y1)0.5))
                           axL(cons(last axL)axL)ayL(cons(last ayL)ayL))))
  (if(< ss 0)(setq xL(reverse xL)yL(reverse yL)
                   rL(append(list(car rL))(reverse rL))))
  (princ(apply 'strcat(mapcar '(lambda(a b c)(strcat a " " b " " c " "))xL yL rL)))
  (princ)
  )


;;柱状ソリッドコード作成
(defun ext_sld
    (ls_shape
     p_origin vec_zdr vec_xdr height_sld str_layer int_color
     / ls_x ls_y ls_r ii jj num tt rrt psL pp1 pp2 pp3 pp4 pd rr mg ft
     scd_reversedsingle scd_forwardsingle  scd_history scd_face scd_loop scd_conesurface
     scd_torussurface scd_coedge scd_edge scd_ellipsecurve scd_point scd_vertex scd_planesurface
     scd_forwardvi scd_forwardi t-31 t314 scd_forwardunknown scd_target scd_straightcurve
     scd_reversed scd_forward at11 gyou ftL pef1 pef2)
  (setq vec_ydr(cross_product vec_zdr vec_xdr)
        )

  (while ls_shape
    (setq ls_x(cons(car ls_shape)ls_x)ls_shape(cdr ls_shape)
          ls_y(cons(car ls_shape)ls_y)ls_shape(cdr ls_shape)
          ls_r(cons(car ls_shape)ls_r)ls_shape(cdr ls_shape)
          )
    )
  
  (setq ls_p(mapcar '(lambda(x y)(list x y 0)) ls_x ls_y))
  ;; (if command_for_alter T(setq ls_r(mapcar '(lambda(a)0)ls_r)))
  (setq ls_dist(mapcar 'distance ls_p(cons(last ls_p)ls_p))
        ls_ang(mapcar 'angle ls_p(append (cdr ls_p)(list(car ls_p))))
        ls_center(mapcar '(lambda( ang0 p0 p1 r / d p2)
                            (cond;;
                             ((= r 0)nil)
                             (T
                              (setq p2(mapcar '(lambda(a b)(* 0.5(+ a b)))p0 p1)
                                    d(sqrt(-(expt r 2)(expt(distance p0 p2)2))))
                              (polar p2(+ ang0(* 0.5 pi))(if(> r 0)d(- d)))
                              )
                             )
                            )
                         ls_ang ls_p(append(cdr ls_p)(list(car ls_p)))ls_r)
        ls_arcdirection(mapcar '(lambda(r)(if(= r 0)nil(if(> r 0)1 -1)))ls_r)
        
        ls_angfan(mapcar '(lambda(a b c r)
                            (if(= r 0)nil
                              ((if(> r 0)+ -)(rem(abs(-(angle a b)(angle a c)))pi))))
                         ls_center ls_p(append (cdr ls_p)(list(car ls_p)))ls_r)
        ls_vec_center(mapcar '(lambda(a b r)(if(= r 0)nil(mapcar '- a b))) ls_p ls_center ls_r)
        )
  
  (setq p_trans(trans-x p_origin (list 0 0 1)vec_zdr )
        ang_xc((lambda( / ls_ang )
                 (setq ls_ang(trans-x vec_xdr (list 0 0 1)vec_zdr))
                 (atan(cadr ls_ang)(car ls_ang))))
        ls_p(mapcar '(lambda(p)
                       (list(+(*(cos ang_xc)(car p))(* -1(sin ang_xc)(cadr p)))
                            (+(*(sin ang_xc)(car p))(*(cos ang_xc)(cadr p)))
                            0))
                    ls_p)
        ls_p(mapcar '(lambda(p)(mapcar '+ p p_trans))ls_p)
        ls_center(mapcar '(lambda(p)
                            (if p(list(+(*(cos ang_xc)(car p))(* -1(sin ang_xc)(cadr p)))
                                      (+(*(sin ang_xc)(car p))(*(cos ang_xc)(cadr p)))
                                      0)))
                         ls_center)
        ls_center(mapcar '(lambda(p)(if p(trans-x(mapcar '+ p p_trans)vec_zdr(list 0 0 1))))
                         ls_center)
        ls_vec_center(mapcar '(lambda(p)
                                (if p(list(+(*(cos ang_xc)(car p))(* -1(sin ang_xc)(cadr p)))
                                          (+(*(sin ang_xc)(car p))(*(cos ang_xc)(cadr p)))
                                          0)))
                             ls_vec_center)
        
        ls_vec_center(mapcar '(lambda(p)(if p(trans-x p vec_zdr(list 0 0 1))))ls_vec_center)
        )

  (setq ls_p_fro(mapcar '(lambda(p)(trans-x p vec_zdr(list 0 0 1)))ls_p)
        ls_p_rea(mapcar '(lambda(p)(mapcar '(lambda(a b)(+ a(* b height_sld)))p vec_zdr))ls_p_fro)
        ls_center_rea(mapcar '(lambda(p)(mapcar '(lambda(a b)(+ a(* b height_sld)))p vec_zdr))ls_center)
        
        )
  ;;辺の長さを求める
  (setq ls_distp_fro(mapcar 'distance ls_p_fro(append(cdr ls_p_fro)(list(car ls_p_fro))))
        ls_distp_rea(mapcar 'distance ls_p_rea(append(cdr ls_p_rea)(list(car ls_p_rea))))
        ls_depth_p(mapcar 'distance ls_p_fro ls_p_rea)
        )

  (setq ii 0 num_point(length ls_p_fro)
        vec_norm_fro
        (unit_vector(cross_product(mapcar '-(cadr ls_p_fro)(car ls_p_fro)) ;底面法線ベクトル
                                  (mapcar '-(caddr ls_p_fro)(car ls_p_fro))))
        p_cent_fro(mapcar '(lambda(a)(/(apply '+(mapcar 'a ls_p_fro))num_point));中心点
                          (list car cadr caddr))
        vec_norm_rea
        (unit_vector(cross_product(mapcar '-(caddr ls_p_rea)(car ls_p_rea))
                                  (mapcar '-(cadr ls_p_rea)(car ls_p_rea))));底面法線ベクトル
        vec_norm_rea(mapcar '- vec_norm_rea)
        p_cent_rea(mapcar '(lambda(a)(/(apply '+(mapcar 'a ls_p_rea))num_point));中心点
                          (list car cadr caddr))
        ls_vec_norm
        (mapcar
         '(lambda(p_fro0 p_fro1 p_rea0 p_rea1
                         / pL ls_point h21 vec_norm dist_plane) 
            (setq ls_point(list p_fro0 p_fro1 p_rea0 p_rea1)
                  vec_norm(unit_vector(cross_product
                                       (mapcar '- p_rea0 p_fro0);側面法線ベクトル
                                       (mapcar '- p_fro1 p_fro0)))
                  dist_plane(apply '+(mapcar '* p_fro0 vec_norm)));面高さ

            (list(mapcar '(lambda(a)(* 0.25(apply '+(mapcar 'a ls_point))))
                         (list car cadr caddr))
                 vec_norm  (trans-x(list 1 0 0)vec_norm(list 0 0 1)))
            )
         ls_p_fro(append(cdr ls_p_fro)(list(car ls_p_fro)))
         ls_p_rea(append(cdr ls_p_rea)(list(car ls_p_rea)))
         )
        )

  ;;行番号リストの作成
  (setq ls_code(list) ;;ls_code
        num_line(* 3 num_point)num_surf(+ 2 num_point)
        ls_num_code(list num_surf num_surf num_surf num_surf(* 2 num_line)
                           num_line num_line(* 2 num_point)(* 2 num_point)))
  (setq ii -2
        ls_sum_code
        (mapcar '(lambda ( n / i a  )
                   (setq a 5 i -1 n(1+ n))
                   (while(<(setq i(1+ i))n)(setq a(+ a(nth i ls_num_code))))
                   (progn a)   )
                (mapcar '(lambda(a)(setq ii(1+ ii)))(cons 0 ls_num_code))))

  (setq ii num_surf ls_repeat(list))
  (while(>(setq ii(1- ii))-1)(setq ls_repeat(cons ii ls_repeat)))
  (setq p1(car ls_p_fro)p2(car ls_p_rea))
  
  (if command_for_alter
      (setq scd_reversedsingle "reversed single #"
            scd_forwardsingle "forward single #"
            scd_history "persubent-acadSolidHistory-attrib $-1 -1 $-1 $-1 $"
            scd_face "face $"                  scd_loop "loop $-1 -1 $-1 $"
            scd_conesurface "cone-surface $-1 -1 $-1 "
            scd_torussurface "torus-surface $-1 -1 $-1 "
            scd_coedge "coedge $-1 -1 $-1 $"   scd_edge "edge $"
            scd_ellipsecurve "ellipse-curve $-1 -1 $-1 "
            scd_point "point $-1 -1 $-1 "      scd_vertex "vertex $-1 -1 $-1 $"
            scd_planesurface "plane-surface $-1 -1 $-1 "
            scd_forwardvi "forward_v I I I I #"
            scd_forwardi "forward I I I I #"
            scd_forwardunknown "forward @7 unknown #"
            scd_target "forward @7 tangent #"
            scd_straightcurve "straight-curve $-1 -1 $-1 "
            scd_reversed "reversed $"          scd_forward "forward $"
            _$ "$" _# "#" _-1 "-1 " _0 "0 " _1 "1 " _3 "3 " _I "I " _F "F "
            )
    (setq scd_reversedsingle "-:):-,:; ,6183: |"
          scd_forwardsingle "90-(>-; ,6183: |"
          scd_history "/:-,*=:1+r><>;L036;W6,+0-&r>++-6= {rn rn {rn {rn {"
          scd_face "9><: {"                    scd_loop "300/ {rn rn {rn {"
          scd_conesurface "<01:r,*-9><: {rn rn {rn "
          scd_torussurface "+0-*,r,*-9><: {rn rn {rn "
          scd_coedge "<0:;8: {rn rn {rn {"     scd_edge ":;8: {"
          scd_ellipsecurve ":336/,:r<*-): {rn rn {rn "
          scd_point "/061+ {rn rn {rn "        scd_vertex "):-+:' {rn rn {rn {"
          scd_planesurface "/3>1:r,*-9><: {rn rn {rn "
          scd_forwardvi "90-(>-;@) V V V V |"
          scd_forwardi "90-(>-; V V V V |"
          scd_forwardunknown "90-(>-; _h *1410(1 |"
          scd_target "90-(>-; _h +>18:1+ |"
          scd_straightcurve ",+->687+r<*-): {rn rn {rn "
          scd_reversed "-:):-,:; {"            scd_forward "90-(>-; {"
          _$ "{" _# "|" _-1 "rn " _0 "o " _1 "n " _3 "l " _I "V " _F "Y "
          )
    )
  
  (setq ls_codefin(append(if command_for_alter(list(cons 1 "End-of-ASM-data ")))
                        (list(cons 290 1)
                             (cons 2 "{00000000-0000-0000-0000-000000000000}")
                             (cons 100 "AcDb3dSolid"))
                        (if command_for_alter(list)(list(cons 350(entlast))))
                        ))
  
  (setq ls_codetrans
        (if command_for_alter
            "transform $-1 -1 1 0 0 0 1 0 0 0 1 0 0 0 1 no_rotate no_reflect no_shear #"
          "+->1,90-2 {rn rn n o o o n o o o n o o o n 10@-0+>+: 10@-:93:<+ 10@,7:>- |")
        ls_codetrans(list(cons 1 ls_codetrans)))

  (setq ls_code
        (append
         ls_code
         (mapcar
          '(lambda(i);;面1
             (cons 1(strcat scd_face(int_to_codestr(+(nth 1 ls_sum_code)i))
                            _-1 _$ _-1 _$
                            (if(= i(1- num_surf)) _-1
                              (int_to_codestr(+(nth 0 ls_sum_code)i 1)))
                            _$(int_to_codestr(+(nth 2 ls_sum_code)i))
                            _$(int_to_codestr 3)
                            _$ _-1
                            _$(int_to_codestr(+(nth 3 ls_sum_code)i))
                            (if(= i 1)scd_forwardsingle scd_reversedsingle)) )  )
          ls_repeat)
         (mapcar
          '(lambda(i);;面2
             (cons 1(strcat  scd_history
                             (int_to_codestr(+(nth 0 ls_sum_code)i))
                             _1 _1 _1 _1 _#))
             )
          ls_repeat)
         (mapcar
          '(lambda(i);;面3
             (cons 1(strcat scd_loop _-1 _$
                            (int_to_codestr
                             (+(nth 4 ls_sum_code)
                               (if(= i 0)0
                                 (if(= i 1)num_point
                                   (+(* 2 num_point)1(* 4(- i 2)))))))
                            _$(int_to_codestr(+(nth 0 ls_sum_code)i))_#)) )
          ls_repeat)))
  
  (setq ls_1(append p_cent_fro vec_norm_fro
                    (unit_vector(mapcar '-(cadr ls_p_fro)(car ls_p_fro))))
        ls_2(append p_cent_rea vec_norm_rea
                    (unit_vector(mapcar '-(cadr ls_p_rea)(car ls_p_rea))))
        ls_code
        (append ls_code
                (list(cons 1(strcat scd_planesurface(lsreal_to_codestr ls_1)
                                    scd_forwardvi))
                     (cons 1(strcat scd_planesurface(lsreal_to_codestr ls_2)
                                    scd_forwardvi)))))
  
  (setq ls_code(append
                ls_code
                (mapcar
                 '(lambda( vec_norm r p_center vec_center rd)
                    (if (= r 0)
                        (cons 1(strcat scd_planesurface 
                                       (lsreal_to_codestr(apply 'append vec_norm))
                                       scd_forwardvi))
                      (cons 1(strcat
                              scd_conesurface(lsreal_to_codestr
                                              (append p_center vec_zdr vec_center(list 1)))
                              _I _I _0(lsreal_to_codestr(list(- rd)(abs r)))scd_forwardi))
                      )
                    )
                 ls_vec_norm ls_r ls_center ls_vec_center ls_arcdirection);;
                )
        )

  (setq int_count_rowcode(1-(last ls_sum_code)))
  (setq ii num_point ls_repeat(list))
  (while(>(setq ii(1- ii))-1)(setq ls_repeat(cons ii ls_repeat)))
  (setq str_1(strcat scd_reversed(int_to_codestr(nth 2 ls_sum_code))))
  (setq ls_code(append;;辺と隣の面-上
                ls_code(mapcar
                        '(lambda(i / jn j2 k1 k2 k3 k4 k5 te)
                           (setq k1(+(nth 4 ls_sum_code)(if(= i 0)num_point i)-1)
                                 k2(+(nth 4 ls_sum_code)(if(= i(1- num_point))0(1+ i)))
                                 k3(+(nth 4 ls_sum_code)(* 2 num_point)(* i 4))
                                 k4(+(nth 5 ls_sum_code)i) )
                           (cons 1(strcat scd_coedge(int_to_codestr k1)
                                          _$(int_to_codestr k2)
                                          _$(int_to_codestr k3)
                                          _$(int_to_codestr k4)
                                          str_1 _0 _$ _-1 _#))
                           ) ls_repeat)));;

  (setq str_1(strcat scd_forward(int_to_codestr(1+(nth 2 ls_sum_code)))))
  (setq ls_code
        (append;;辺と隣の面-上
         ls_code(mapcar
                 '(lambda(i / jn j2 k1 k2 k3 k4 k5 te)
                    (setq k1(+(nth 4 ls_sum_code)(if(= i(1- num_point))0(1+ i))num_point)
                          k2(+(nth 4 ls_sum_code)(if(= i 0)num_point i)num_point -1)
                          k3(+(nth 4 ls_sum_code)(* 2 num_point)1(* i 4))
                          k4(+(nth 5 ls_sum_code)i num_point))
                    (cons 1(strcat scd_coedge(int_to_codestr k1)
                                   _$(int_to_codestr k2)
                                   _$(int_to_codestr k3)
                                   _$(int_to_codestr k4)
                                   str_1 _0 _$ _-1 _#))
                    ) ls_repeat)));;
  
  (setq ls_code
        (append
         ls_code
         (apply 'append
                (mapcar
                 '(lambda(i / k0 k1 k20 k21 k3 k4 k5 tdL)
                    (setq k5(+(nth 2 ls_sum_code)2 i)
                          k0(+(nth 4 ls_sum_code)(* 2 num_point)(* i 4))
                          k1(+(nth 4 ls_sum_code)i)
                          k20(if(= i 0)(1-(nth 5 ls_sum_code))(1- k0))
                          k21(if(= i(1- num_point))
                                 (+(nth 4 ls_sum_code)(* 2 num_point)2)
                               (+ k0 6))
                          k3(+(nth 5 ls_sum_code)i)
                          k4(+(nth 5 ls_sum_code)num_point
                              i 1(if(= i(1- num_point))0 num_point))
                          tdL(list _-1 _-1 _-1 _-1)
                          )
                    (list(cons 1(strcat
                                 scd_coedge(int_to_codestr(+ k0 3))
                                 _$(int_to_codestr(+ k0 2))
                                 _$(int_to_codestr k1 )
                                 _$(int_to_codestr(+ k3 0))
                                 scd_forward(int_to_codestr k5)_0
                                 _$(nth 0 tdL)_#))
                         (cons 1(strcat
                                 scd_coedge(int_to_codestr(+ k0 2))
                                 _$(int_to_codestr(+ k0 3))
                                 _$(int_to_codestr(+ k1 num_point))
                                 _$(int_to_codestr(+ k3 num_point))
                                 scd_reversed(int_to_codestr k5)_0
                                 _$(nth 1 tdL)_#))
                         (cons 1(strcat
                                 scd_coedge(int_to_codestr(+ k0 0))
                                 _$(int_to_codestr(+ k0 1))
                                 _$(int_to_codestr k20)
                                 _$(int_to_codestr(+ k3 num_point num_point))
                                 scd_forward(int_to_codestr k5)_0
                                 _$(nth 2 tdL)_#))
                         (cons 1(strcat
                                 scd_coedge(int_to_codestr(+ k0 1))
                                 _$(int_to_codestr(+ k0 0))
                                 _$(int_to_codestr k21)
                                 _$(int_to_codestr k4)
                                 scd_reversed(int_to_codestr k5)_0
                                 _$(nth 3 tdL)_#))
                         )
                    )
                 ls_repeat))))

  
  (setq ls_code
        (append
         ls_code
         (mapcar;;辺の長さ-下
          '(lambda(i d angfan / s jt )
             (setq jt(if(= i(1- num_point))(int_to_codestr(nth 7 ls_sum_code))
                       (int_to_codestr(+(nth 7 ls_sum_code)1 i))))
             (cons 1(strcat scd_edge _-1 _-1 _$ _-1

                            _$(int_to_codestr(+(nth 7 ls_sum_code)i ))_0
                            _$ jt(lsreal_to_codestr(list(if angfan angfan d)))
                            
                            ;; (if angfan
                            ;;     (if(> angfan 0)
                            ;;         (strcat
                            ;;          _$(int_to_codestr(+(nth 7 ls_sum_code)i))_0
                            ;;          _$ jt(lsreal_to_codestr(list angfan )) )
                            ;;       (strcat
                            ;;        _$(int_to_codestr(+(nth 7 ls_sum_code)i))
                            ;;        (lsreal_to_codestr(list angfan )) _$ jt _0 )
                            ;;       )
                            ;;   (strcat
                            ;;    _$(int_to_codestr(+(nth 7 ls_sum_code)i))_0
                            ;;    _$ jt(lsreal_to_codestr(list d)) )
                            ;;   )
                            
                            _$(int_to_codestr(+(nth 4 ls_sum_code)(* 2 num_point)(* 4 i)))
                            _$(int_to_codestr(+(nth 6 ls_sum_code)i))
                            scd_forwardunknown)))
          ls_repeat ls_distp_fro ls_angfan)
         (mapcar;;辺の長さ-上
          '(lambda(i d angfan / s jt )
             (setq jt(if(= i(1- num_point))(int_to_codestr(+(nth 7 ls_sum_code)num_point))
                       (int_to_codestr(+(nth 7 ls_sum_code)num_point 1 i))))
             (cons 1(strcat scd_edge _-1 _-1 _$ _-1
                            
                            _$(int_to_codestr(+(nth 7 ls_sum_code)i num_point))_0
                            _$ jt(lsreal_to_codestr(list(if angfan angfan d)))
                            
                            _$(int_to_codestr(+(nth 4 ls_sum_code)1(* 2 num_point)(* 4 i)))
                            _$(int_to_codestr(+(nth 6 ls_sum_code)i num_point))
                            scd_forwardunknown)))
          ls_repeat ls_distp_rea ls_angfan)
         (mapcar;;辺の長さ-縦
          '(lambda(i d  / tt ds k3);;18:1
             ;; (setq tt scd_forwardunknown)
             (setq ds(lsreal_to_codestr(list d))
                   k3(int_to_codestr
                      (if(= i 0)(+(nth 5 ls_sum_code)-1)
                        (+(nth 4 ls_sum_code)(* 2 num_point)2(* 4 i))) ))
             (cons 1(strcat scd_edge _-1 _-1 _$ _-1
                            _$(int_to_codestr(+(nth 7 ls_sum_code)i num_point))_0
                            _$(int_to_codestr(+(nth 7 ls_sum_code)i)) ds;;長さ
                            _$ k3
                            _$(int_to_codestr
                               (+(nth 6 ls_sum_code)i num_point num_point))
                            scd_forwardunknown)))
          ls_repeat ls_depth_p )))

  (setq ls_code
        (append
         ls_code
         (mapcar;;線の向き下  ;;elli
          '(lambda(p1 p2 d r p_center vec_center arcdire angfan / tt)
             (setq tt(lsreal_to_codestr(append p1(unit_vector(mapcar '- p2 p1)))))
             (if (= r 0)
                 (cons 1(strcat scd_straightcurve tt
                                _I _I _#))
               ;;_F _0 _F (lsreal_to_codestr(list d))_#))
               (cons 1(strcat scd_ellipsecurve
                              (lsreal_to_codestr
                               (append p_center(if(if command_for_alter(> arcdire 0)T)
                                                   vec_zdr(mapcar '- vec_zdr))
                                       vec_center(list 1)))
                              _I _I _#))
                              ;;_F _0 _F(lsreal_to_codestr(list angfan))_#))
               )
             )
          ls_p_fro(append(cdr ls_p_fro)(list(car ls_p_fro)))ls_distp_fro
          ls_r ls_center ls_vec_center ls_arcdirection ls_angfan
          )
         
         (mapcar;;線の向き上  ;;elli
          '(lambda(p1 p2 d r p_center vec_center arcdire angfan / tt)
             (setq tt(lsreal_to_codestr(append p1(unit_vector(mapcar '- p2 p1)))))
             (if (= r 0)
                 (cons 1(strcat scd_straightcurve tt
                                _I _I _#))
               ;;_F _0 _F (lsreal_to_codestr(list d))_#))
               (cons 1(strcat scd_ellipsecurve
                              (lsreal_to_codestr
                               (append p_center(if(if command_for_alter(> arcdire 0)T)
                                                   vec_zdr(mapcar '- vec_zdr))
                                       vec_center(list 1)))
                              _I _I _#))
                              ;;_F _0 _F(lsreal_to_codestr(list angfan))_#))
               )
             )
          ls_p_rea(append(cdr ls_p_rea)(list(car ls_p_rea)))ls_distp_rea
          ls_r ls_center_rea ls_vec_center ls_arcdirection ls_angfan
          )
         (mapcar;;線の向き縦
          '(lambda(p1 p2 / tt)
             (setq tt(lsreal_to_codestr(append p1(unit_vector(mapcar '- p2 p1)))))
             (cons 1(strcat scd_straightcurve tt " " _I _I _#))
             )
          ls_p_fro ls_p_rea)))

  
  (setq ls_code
        (append
         ls_code
         (mapcar;;点と辺-下
          '(lambda(i x)
             (cond
              ((= i 0)
               (cons 1(strcat scd_vertex
                              (int_to_codestr(+(nth 5 ls_sum_code)num_point -1))_1
                              _$(int_to_codestr(+(nth 8 ls_sum_code)i))" " _#)))
              (T
               (cons 1(strcat scd_vertex
                              (int_to_codestr(+(nth 5 ls_sum_code)i))" " _0
                              _$(int_to_codestr(+(nth 8 ls_sum_code)i))" " _#)))
              ))
          ls_repeat ls_p_fro)
         (mapcar;;点と辺-上
          '(lambda(i x)
             (cond
              ((= i 0)
               (cons 1(strcat scd_vertex
                              (int_to_codestr(+(nth 5 ls_sum_code)num_point num_point -1))_1
                              _$(int_to_codestr(+(nth 8 ls_sum_code)i num_point))" " _#)))
              (T
               (cons 1(strcat scd_vertex(int_to_codestr(+(nth 5 ls_sum_code)i num_point))_0
                              _$(int_to_codestr(+(nth 8 ls_sum_code)i num_point))" "_#)))
              ))
          ls_repeat ls_p_fro)))

  (setq ls_code(append ls_code
                       (mapcar ;;点-下
                        '(lambda(p)(cons 1(strcat scd_point(lsreal_to_codestr p)_#)))ls_p_fro)
                       (mapcar;;点-上
                        '(lambda(p)(cons 1(strcat scd_point(lsreal_to_codestr p)_#)))ls_p_rea)
                       ))
  
  (setq str_count(int_to_codestr(1+ int_count_rowcode)))
  
  (setq ls_codehead
        (if command_for_alter
            (list
             (cons 0 "3DSOLID")(cons 8 str_layer)(cons 62 int_color)
             (cons 100 "AcDbEntity")(cons 100 "AcDbModelerGeometry")(cons 70 1)
             (cons 1 (strcat "22300 " str_count "2 1         "))
             (cons 1 "16 Autodesk AutoCAD 20 ASM 229.8.0.65535 NT 0")
             (cons 1 "1 9.9999999999999995e-007 1e-010 ") 
             (cons 1 "asmheader $-1 -1 @13 229.8.0.65535 #") 
             (cons 1 "body $-1 -1 $-1 $2 $-1 $4 #") 
             (cons 1 "lump $-1 -1 $-1 $-1 $3 $1 #") 
             (cons 1 "shell $-1 -1 $-1 $-1 $-1 $5 $-1 $2 #") 
             )
          (list
           (cons 0 "3DSOLID")(cons 8 str_layer)(cons 62 int_color)
           (cons 100 "AcDbEntity")(cons 100 "AcDbModelerGeometry")(cons 70 1)
           (cons 1 (strcat "mmloo " str_count "m k         "))
           (cons 1 "ni ^*+0;:,4 ^*+0\\^[ mo ^LR mmjqnqoqijjlj QK o  ")
           (cons 1 "n fqfffffffffffffffjkh:roh nqooooooooooooooooli:rno ")
           (cons 1 ">,27:>;:- {rn rn _nl mmjqnqoqijjlj |")
           (cons 1 "=0;& {rn rn {rn {m {rn {k |")
           (cons 1 "3*2/ {rn rn {rn {rn {l {n |")
           (cons 1 ",7:33 {rn rn {rn {rn {rn {j {rn {m |")
           )
          )
        )

  (entmakex(append ls_codehead ls_codetrans ls_code ls_codefin))
  )



;;ext_sld_end

(defun carxy( p / )(progn(list(car p)(cadr p))))
(defun carxyz( p z / )(progn(list(car p)(cadr p)z)))
(defun cross_product ;;
    ( v1 v2 / )
  (if(null(caddr v1))(setq v1(carxyz v1 0)))
  (if(null(caddr v2))(setq v2(carxyz v2 0)))
  (mapcar '(lambda(a b)
             (-(*(a v1)(b v2))(*(a v2)(b v1))))
          (list cadr caddr car)(list caddr car cadr))
  )
(defun vh-xyz( vec_in / real_x real_y real_z dist_0)
  (setq vec_z((lambda( / real_dist )
                 (setq real_dist(distance(list 0 0 0)vec_in))
                 (if(< real_dist 1e-8)(list 0 0 0)
                   (mapcar '/ vec_in(list real_dist real_dist real_dist)))))
        real_x(car vec_z)real_y(cadr vec_z)real_z(caddr vec_z) )
  (if(and(<=(abs real_x)0.015625)(<=(abs real_y)0.015625))
      (setq real_tanxz(expt(/ real_x real_z)2)
            real_zz(*(if(>(* real_x real_z)0)-1 1)(sqrt(/ real_tanxz(1+ real_tanxz))))
            vec_x(list (*(if(> real_z 0)1 -1)(sqrt(- 1(expt real_zz 2)))) 0 real_zz))
    (setq vec_x(list(- real_y)real_x 0) dist_0(distance(list 0 0 0)vec_x)
          vec_x(mapcar '(lambda(a)(/ a dist_0 1.0))vec_x)) )
  (setq vec_y(mapcar '(lambda(a b)(-(*(a vec_z)(b vec_x))(*(a vec_x)(b vec_z))))
                     (list cadr caddr car)(list caddr car cadr))
        vec_z(mapcar '(lambda(a b)(-(*(a vec_x)(b vec_y))(*(a vec_y)(b vec_x))))
                     (list cadr caddr car)(list caddr car cadr))
             )
  (list vec_x vec_y vec_z)
  )
(if(null command_for_alter)(setq trans-x trans)
  (defun trans-x( point_0 vec_1 vec_2 / vec_x vec_y vec_z)
    (vh-xyz vec_1)
    (setq point_0(mapcar '(lambda(a b c)
                            (apply '+(mapcar '* point_0(list a b c))))
                          vec_x vec_y vec_z))
    (mapcar '(lambda(a)(apply '+(mapcar '* point_0 a)))(vh-xyz vec_2))
    )
  )
(defun unit_vector( vv / dd );;単位ベクトル
  (setq dd(distance(list 0 0 0)vv))
  (if(< dd 1e-8)(list 0 0 0)(mapcar '(lambda(a)(/ a dd))vv))
  )
(defun inclist( n1 n2 / iL );;順に増える整数リストの作成
  (while(>(setq n2(1- n2))(1- n1))(setq iL(cons n2 iL)))(progn iL))

;;リストの前から順に取り出す
(defun take_list (lst n / result)
  (setq result '())
  (while (and lst (> n 0))
    (setq result (cons (car lst)result)lst (cdr lst) n(1- n)) )
  (reverse result)
  )

(defun drop_list (lst n)
  (while (and lst (> n 0))(setq lst (cdr lst) n(1- n)) )
  lst )

(defun double_list (lst)
  (if lst(cons(car lst)(cons(car lst)(double_list(cdr lst))))) )

(if command_for_alter
    (progn
      (defun int_to_codestr( a )(strcat(rtos a 2 0)" "))
      (defun lsreal_to_codestr( a )
        (apply 'strcat(mapcar '(lambda(b)(if(=(-(atof(rtos b 2))(fix b))0)
                                             (strcat(rtos b 2 0)" ")
                                           (strcat(rtos b 2 16)" "))) a)));;
      )
  (progn
    (defun int_to_codestr( a )(strcat(solid_txt_xcm(rtos a 2 0))" "))
    (defun lsreal_to_codestr( a );;数値変換
      (apply
       'strcat
       (mapcar
        '(lambda(b)
           (strcat(solid_txt_xcm(rtos b 2(if(=(-(atof(rtos b 2))(fix b))0)0 16)))" ") )
        a)))
    )
  )
(defun solid_txt_xcm( str / str_out str_one int_ascii)
  (setq str_out "")
  (while(/= str "")
    (setq str_one(substr str 1 1) int_ascii(ascii str_one))
    (if(or(< int_ascii 33)(> int_ascii 126))T(setq str_one(chr(- 159 int_ascii))))
    (setq str_out(strcat str_out str_one)str(substr str 2))
    )
  str_out
  )


(princ)
